home *** CD-ROM | disk | FTP | other *** search
/ Shareware Grab Bag / Shareware Grab Bag.iso / 010 / antdesgn.arc / APERTURE.BAS next >
Encoding:
BASIC Source File  |  1980-01-01  |  4.0 KB  |  152 lines
  1. 10 REM APERTURE ANTENNA CHARACTERISTICS
  2. 20 REM "ANTENNA DESIGN USING PERSONAL COMPUTERS"
  3. 30 PI=3.14159
  4. 40 DEF FNLOG10(X)=.4343*LOG(X)
  5. 50 KEY OFF
  6. 60 CLS
  7. 70 COLOR 1,0
  8. 80 PRINT "THIS PROGRAM CALCULATES APERTURE ANTENNA CHARACTERISTICS"
  9. 90 PRINT
  10. 100 COLOR 4,0
  11. 110 PRINT
  12. 120 PRINT "APERTURE TYPES AVAILABLE:"
  13. 130 PRINT "          1-LINE SOURCE"
  14. 140 PRINT "          2-RECTANGULAR APERTURE"
  15. 150 PRINT "          3-CIRCULAR APERTURE"
  16. 160 PRINT "          4-EXIT PROGRAM"
  17. 170 PRINT
  18. 180 INPUT "WHICH APERTURE TYPE DO YOU WANT(1,2,3,4)";AP
  19. 190 IF AP=1 THEN GOTO 240
  20. 200 IF AP=2 THEN GOTO 610
  21. 210 IF AP=3 THEN GOTO 960
  22. 220 IF AP=4 THEN GOTO 1490
  23. 230 GOTO 180
  24. 240 REM LINE SOURCE CASE
  25. 250 PRINT "LINE SOURCE DISTRIBUTIONS AVAILABLE:"
  26. 260 PRINT "          1-UNIFORM"
  27. 270 PRINT "          2-TRIANGULAR"
  28. 280 PRINT "          3-COSINE"
  29. 290 PRINT "          4-COSINE SQUARED"
  30. 300 PRINT
  31. 310 INPUT "WHICH DISTRIBUTION DO YOU WANT(1,2,3,4)";LS
  32. 320 IF LS=1 THEN GOTO 370
  33. 330 IF LS=2 THEN GOTO 430
  34. 340 IF LS=3 THEN GOTO 490
  35. 350 IF LS=4 THEN GOTO 550
  36. 360 GOTO 310
  37. 370 GOSUB 1210
  38. 380 GOSUB 1240
  39. 390 HPBW=50.7*XLAM/L
  40. 400 SLL=-13.3
  41. 410 D=2*L/XLAM
  42. 420 GOTO 1310
  43. 430 GOSUB 1210
  44. 440 GOSUB 1240
  45. 450 HPBW=73.3*XLAM/L
  46. 460 SLL=-26.6
  47. 470 D=1.5*L/XLAM
  48. 480 GOTO 1310
  49. 490 GOSUB 1210
  50. 500 GOSUB 1240
  51. 510  HPBW=68.2*XLAM/L
  52. 520 SLL=-23!
  53. 530 D=1.62*L/XLAM
  54. 540 GOTO 1310
  55. 550 GOSUB 1210
  56. 560 GOSUB 1240
  57. 570 HPBW=82.5*XLAM/L
  58. 580 SLL=-31.7
  59. 590 D=1.33*L/XLAM
  60. 600 GOTO 1310
  61. 610 REM RECTANGULAR APERTURE CASE
  62. 620 PRINT "RECTANGULAR APERTURE DISTRIBUTIONS AVAILABLE:"
  63. 630 PRINT "          1-UNIFORM IN E AND H-PLANES"
  64. 640 PRINT "          2-UNIFORM IN E-PLANE, COSINE IN H-PLANE(TE 10 MODE)"
  65. 650 PRINT "          3-COSINE IN E AND H-PLANES"
  66. 660 PRINT
  67. 670 INPUT "WHICH DISTRIBUTION DO YOU WANT(1,2,3)";RD
  68. 680 IF RD=1 THEN GOTO 720
  69. 690 IF RD=2 THEN GOTO 800
  70. 700 IF RD=3 THEN GOTO 880
  71. 710 GOTO 670
  72. 720 GOSUB 1210
  73. 730 GOSUB 1260
  74. 740 HPBWE=50.6*XLAM/B
  75. 750 HPBWH=50.6*XLAM/A
  76. 760 SLLE=-13.3
  77. 770 SLLH=-13.3
  78. 780 D=4*PI*A*B/(XLAM*XLAM)
  79. 790 GOTO 1390
  80. 800 GOSUB 1210
  81. 810 GOSUB 1260
  82. 820 HPBWE=50.6*XLAM/B
  83. 830 HPBWH=68.8*XLAM/A
  84. 840 SLLE=-13.3
  85. 850 SLLH=-23!
  86. 860 D=.81*4*PI*A*B/(XLAM*XLAM)
  87. 870 GOTO 1390
  88. 880 GOSUB 1210
  89. 890 GOSUB 1260
  90. 900 HPBWE=68.8*XLAM/B
  91. 910 HPBWH=68.8*XLAM/A
  92. 920 SLLE=-23
  93. 930 SLLH=-23
  94. 940 D=.656*4*PI*A*B/(XLAM*XLAM)
  95. 950 GOTO 1390
  96. 960 REM CIRCULAR APERTURE CASE
  97. 970 PRINT "CIRCULAR APERTURE DISTRIBUTIONS AVAILABLE:"
  98. 980 PRINT "          1-UNIFORM"
  99. 990 PRINT "          2-TE 11 WAVEGUIDE MODE"
  100. 1000 PRINT
  101. 1010 INPUT "WHICH DISTRIBUTION DO YOU WANT(1,2)";CD
  102. 1020 IF CD=1 THEN GOTO 1050
  103. 1030 IF CD=2 THEN GOTO 1130
  104. 1040 GOTO 1010
  105. 1050 GOSUB 1210
  106. 1060 GOSUB 1290
  107. 1070 HPBWE=29.2*XLAM/A
  108. 1080 HPBWH=HPBWE
  109. 1090 SLLE=-17.6
  110. 1100 SLLH=-17.6
  111. 1110 D=(2*PI*A/XLAM)^2
  112. 1120 GOTO 1390
  113. 1130 GOSUB 1210
  114. 1140 GOSUB 1290
  115. 1150 HPBWE=29.2*XLAM/A
  116. 1160 HPBWH=37*XLAM/A
  117. 1170 SLLE=-17.6
  118. 1180 SLLH=-26.2
  119. 1190 D=10.5*PI*(A/XLAM)^2
  120. 1200 GOTO 1390
  121. 1210 INPUT "WHAT IS THE FREQUENCY(MHz)";FMC
  122. 1220 XLAM=300/FMC
  123. 1230 RETURN
  124. 1240 INPUT "WHAT IS THE LINE SOURCE LENGTH(meters)";L
  125. 1250 RETURN
  126. 1260 INPUT "WHAT IS THE APERTURE SIZE IN THE E-PLANE(meters)";B
  127. 1270 INPUT "WHAT IS THE APERTURE SIZE IN THE H-PLANE(meters)";A
  128. 1280 RETURN
  129. 1290 INPUT "WHAT IS THE CIRCULAR APERTURE RADIUS(meters)";A
  130. 1300 RETURN
  131. 1310 REM PRINT OUT LINE SOURCE DATA
  132. 1320 DDB=10*FNLOG10(D)
  133. 1330 PRINT
  134. 1340 COLOR 14,0
  135. 1350 PRINT USING "HALF-POWER BEAMWIDTH(degrees)=###.##";HPBW
  136. 1360 PRINT USING "SIDELOBE LEVEL(dB)=###.#";SLL
  137. 1370 PRINT USING "DIRECTIVITY=###.#, =##.# dB";D,DDB
  138. 1380 GOTO 90
  139. 1390 REM PRINT OUT APERTURE DATA
  140. 1400 DDB=10*FNLOG10(D)
  141. 1410 PRINT
  142. 1420 COLOR 14,0
  143. 1430 PRINT USING "E-PLANE HP BEAMWIDTH(degrees)=###.##";HPBWE
  144. 1440 PRINT USING "H-PLANE HP BEAMWIDTH(degrees)=###.##";HPBWH
  145. 1450 PRINT USING "E-PLANE SIDELOBE LEVEL(dB)=###.#";SLLE
  146. 1460 PRINT USING "H-PLANE SIDELOBE LEVEL(dB)=###.#";SLLH
  147. 1470 PRINT USING "DIRECTIVITY=###.#, =##.# dB";D,DDB
  148. 1480 GOTO 90
  149. 1490 COLOR 7,0
  150. 1500 KEY ON
  151. 1510 END
  152.